<%@ CodePage=65001 Language="VBScript"%>
<% Option Explicit %>
<!-- #include file="../includes/include.asp"-->
<!-- #include file="../includes/include-albums.asp"-->
<!-- #include file="../includes/include-upload.asp"-->
<% sBBSLangPage = "albums"
   BBS.SetupBBS
   BBS.SetScheme(0)

   dim iAlbumID, iPhotoID, iModuleUserLevel, sDescription, bError, File, SQL, sComponent, vAlbumInfo, vPhotoInfo, Uploader, objFile

   ' Check for permission
   if not(BBS.HasPermission(PERM_ViewBBS, -1)) then response.redirect sBBSForumRoot & "/logon.asp?error=needregistration"
   if not(BBS.HasPermission(PERM_AlbumView, -1)) then response.redirect sBBSForumRoot & "/restricted-page.asp"

   if dictConfiguration("bENABLEPHOTOALBUMS") = 0 then response.redirect "../category-view.asp"
   if iBBSUserLevel < USERLEVEL_user then response.redirect "../category-view.asp"

   iAlbumID = request.querystring("albumid")
   vAlbumInfo = Albums.GetAlbumInfo(iAlbumID)
   if vAlbumInfo(AI_AlbumID) < 0 then response.redirect "photo-main.asp"
   iModuleUserlevel = BBS.GetUserlevel(MODULE_Albums, -1)

   ' Get photo information
   vPhotoInfo = Albums.GetPhotoInfo(request.querystring("photoid"))

   ' Something isn't right. Mismatching albumid and photoid
   if vPhotoInfo(PI_AlbumID) <> vAlbumInfo(AI_AlbumID) then response.redirect "photo-main.asp"

   if ucase(vAlbumInfo(AI_Username)) <> ucase(sBBSUsername) and iModuleUserlevel <= USERLEVEL_User then response.redirect "photo-controlpanel.asp"

   if request.form("action") = "updatedescription" then
     SQL = "update photos set description='" & BBS.ValidateSQL(request.form("description")) & "' where photoid=" & BBS.ValidateNumeric(vPhotoInfo(PI_PhotoID))
     dbConnection.execute SQL
     BBS.AddQuery(SQL)
     vPhotoInfo(PI_Description) = request.form("description")
     response.redirect "photo-thumbnails.asp?msg=update&albumid=" & iAlbumID
   end if

   if request.form("action") = "deletephoto" then
     Albums.DeletePhoto(request.querystring("photoid"))
     vAlbumInfo(AI_PhotoCount)  = Albums.GetNumberOfPhotos(vAlbumInfo(AI_AlbumID))
     Albums.EditAlbum(vAlbumInfo)
     response.redirect "photo-thumbnails.asp?albumid=" & vAlbumInfo(AI_AlbumID) & "&amp;photoid=" & vPhotoInfo(PI_PhotoID)
   end if


   dictEnvironment("U-EDITPHOTO")       = "image-edit.asp?albumid=" & vAlbumInfo(AI_AlbumID) & "&amp;photoid=" & vPhotoInfo(PI_PhotoID) & "&amp;action=updatephoto"
   dictEnvironment("U-EDITDESCRIPTION") = "image-edit.asp?albumid=" & vAlbumInfo(AI_AlbumID) & "&amp;photoid=" & vPhotoInfo(PI_PhotoID)

   dictEnvironment("V-ALBUMINFO")       = vAlbumInfo
   dictEnvironment("V-PHOTOINFO")       = vPhotoInfo

   dictEnvironment.add "V-TITLE", dictLanguage.item("ALBUMS-TITLE")
   dictEnvironment.add "C-SHOWRANDOMQUOTES", dictConfiguration("bDISPLAYBBSQUOTES")
   if iBBSUserLevel >= USERLEVEL_SupportAdministrator then dictEnvironment.add "C-SHOWADMINLINK", 1

%>
<!-- #include file="../includes/header.asp" -->
<% Filesystem.ExecuteBBSTemplate("/photos/image-edit.asp") %>
<!-- #include file="../includes/footer.asp" -->